VBScript如何监控并结束指定进程

这篇文章主要为大家展示了“VBScript如何监控并结束指定进程”，内容简而易懂，条理清晰，希望能够帮助大家解决疑惑，下面让小编带领大家一起研究并学习一下“VBScript如何监控并结束指定进程”这篇文章吧。

运行效果图：

代码（monprocess.vbs）：

复制代码 代码如下:

On Error Resume Next

strComputer = "."
arrTargetProcs = Array("calc.exe", "notepad.exe", "other.exe")
'数组里为要监视的进程名

Set SINK = WScript.CreateObject("WbemScripting.SWbemSink","SINK_")
Set objWMIService = GetObject("winmgmts:" & _
 "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
objWMIService.ExecNotificationQueryAsync SINK, _
 "SELECT * FROM __InstanceCreationEvent WITHIN 1 " & _
  "WHERE TargetInstance ISA 'Win32_Process'"
Wscript.Echo "Are monitoring processes ..."
Do
 WScript.Sleep 1000
Loop

'***************************************************************************
Sub SINK_OnObjectReady(objLatestEvent, objAsyncContext)
'Trap asynchronous events.
 For Each strTargetProc In arrTargetProcs
  If LCase(objLatestEvent.TargetInstance.Name) = LCase(strTargetProc) Then
   intReturn = objLatestEvent.TargetInstance.Terminate
   If intReturn = 0 Then
    Wscript.Echo "Time: " & Now & ", Succeed!" & chr(9) & _
     "Name: " & objLatestEvent.TargetInstance.Name
    Else
    Wscript.Echo "Time: " & Now & ", Failed!" & chr(9) & _
     "Name: " & objLatestEvent.TargetInstance.Name
   End If
  End If
 Next
End Sub

以上是“VBScript如何监控并结束指定进程”这篇文章的所有内容，感谢各位的阅读！相信大家都有了一定的了解，希望分享的内容对大家有所帮助，如果还想学习更多知识，欢迎关注编程网行业资讯频道！